SAS-Macros mit eingebauter Hilfe-Funktion schreiben

Einführung

Kurz: ein Macro wird aufgerufen und hat zu funktionieren. Schön ist es dabei, wenn man herausbekommen kann, wie das Macro aufgerufen wird, und, wenn es dann doch Probleme gibt, wie es funktioniert.

Der erste Schritt ist ein eingebautes Hilfe-System: Das Macro erzählt dem Benutzer, wie es behandelt werden möchte.

Natürlich gibt es immer Menschen, die immer alles wissen und dann trotzdem was falsch machen. Auch denen können wir helfen, indem wir die Parameter sorgfältig prüfen, bevor Fehler in Proc- oder Data-Schritten Rätsel aufgeben.

Wenn es trotzdem zu Problemen kommt, oder auch nur um zu verstehen, wie das Macro arbeitet, verwenden manche vor dem Macro-Aufruf die Option MPRINT. Dann wird im Log der erzeugte SAS-Code ausgegeben. Auch dabei können wir dem Benutzer helfen, indem wir ihm zusätzliche Kommentare anzeigen.
 

Die Hilfe-Funktion

          %print ( hilfe=Ja gerne );

          %MACRO print (data,var,by=,pagesize=60,linesize=72 );

          %print (sasuser.fitness,pagesize= ,linesize=120 );

Für die Hilfe-Funktion geben wir jetzt einfach einen zusätzlichen Parameter an, der sie aktiviert - und weil ich mir nie merken kann, ob es jetzt HILFE oder HELP heißt, nehme ich gleich drei:

          %MACRO print (data,var,by=,pagesize=60,linesize=72, 
                     info=n, help=n, hilfe=n);

          %IF %QUOTE(&info.&help.&hilfe) NE nnn %THEN %DO;
              %PUT %NRSTR(Dieses Macro druckt eine Datei mit PROC print);
              %PUT %NRSTR(Aufruf %print%( data   * Dateiname);
              %PUT %NRSTR( optional:);
              %PUT %NRSTR(               ,var    * Variablen);
              %PUT %NRSTR(               ,by=    * Variablen für Untergruppen-Verarbeitung);
              %PUT   %STR(               ,linesize=&linesize    * Zeilenenlänge);
              %PUT   %STR(               ,pagesize=&pagesize    * Seitenlänge);
              %PUT %NRSTR(             %););
              %RETURN;     %* Vor derSAS-Version 9 stand hier %GOTO ende mit einem Sprungziel am Macro-ende;
          %END;

Parameter-Prüfung

• Sind die notwendigen Parameter angegeben?
• Existiert die SAS-Datei?
• Ganz nette Zeitgenossen prüfen auch noch, ob es die Variablen in der Datei gibt, ob sie den richtigen Typ haben, usw.

          %IF %SUPERQ(data) EQ %THEN %DO;
              %PUT Fehler: Angabe des Dateinamens fehlt;
              %PUT Hilfe mit info=Y;
              %RETURN;
          %END;

          %IF NOT %SYSFUNC(EXIST(&data)) %THEN %DO;
              %PUT Fehler: Datei &data nicht gefunden;
              %PUT Hilfe mit info=Y;
              %RETURN; %* Ab Version 9, vorher %GOTO ende;
          %END;

Ach ja, wer ganz penibel ist schreibt z.B.:

          %IF %WSICHDV ( DATA   = &data,
                         ANYVAR = &var,
                         NUMVAR = &sumvar)
                NE OK  %THEN %DO;
              %PUT Verarbeitung aufgrund dieser Fehler abgebrochen;
              %PUT Hilfe mit info=Y;
              %RETURN;
          %END;

• ob die Datei existiert
• ob die Variablen in der Datei sind,
• ob die Variablen den vorrausgesetzten Typ haben (numerisch oder character)

Abbrüche nach Macro-Fehlern

Der Autor bevorzugt bei produktiv eingesetzten Programmen die kräftige Methode des Job-Abbruchs:

          %IF NOT %SYSFUNC(EXIST(&data)) %THEN %DO;
              %PUT Die Datei &data wurde nicht gefunden,;
              %PUT deshalb wird der Job vorsichtshalber abgebrochen.;
	      %ABORT ABEND 12;
        /* Vor der Version 9 wurde hierzu ein Datastep benötigt: 
              DATA _NULL_;
                  ABORT ABEND 12;
              RUN;
        */ 
          %END;

Etwas weniger brutal ist die Erzeugung eines Syntaxfehlers, der anschließ in der automatischen Macro-Variablen &SYSERR abgefragt werden kann. Man kann auch mit der Macrovariablen &SYSENV zwischen interaktiver und Batch-Verarbeitung unterscheiden.
Beispiel:

          %IF NOT %SYSFUNC(EXIST(&data)) %THEN %DO;
              %PUT Die Datei &data wurde nicht gefunden,;
              %IF &SYSENV EQ BACK %THEN %DO;
                  %PUT deshalb wird der Job vorsichtshalber abgebrochen.;
                  %ABORT Abend 12;
              %END;
              * Syntaxfehler erzeugen;
              DATA _NULL_;
                  Das ist ein Syntaxfehler zum Setzen von SYSERR;
              RUN;
              %RETURN; 
          %END;

Kommentare für die Ausgabe mit der Option MPRINT

Manchmal möchte man aber auch wissen, welchen Code das Macro erzeugt. In diesem Fall hilft die SAS-Option MPRINT. Der vom Macro erzeugte Code wird dann im SAS-Log ausgegeben. Dieser Code kann mit den Kommentaren im Stil

* Kommentar;

%* Macro Kommentar;

/* Kommentar-Text zum Code */;

Im folgenden Beispiel wird dies verdeutlicht.
 
 

Beispiel

%MACRO print(data,
             var=,
             info=n,help=n,hilfe=n);
/*---------------------------------------------------------
   Macro zur Demonstration der Macro-Hilfe, der
   Parameter-Prüfung und der Wirkung von Kommentaren

   Beitrag zum SAS-Anwenderhandbuch der Uni Heidelberg
   Wilfried Schollenberger  < wisch@ws-unternehmensberatung.de >
   WS Unternehmensberatung und Controlling-Systeme
----------------------------------------------------------*/

%* Hilfe-Funktion;

%IF %QUOTE(&info.&help.&hilfe) NE nnn %THEN %DO;
    %PUT %NRSTR(Dieses Macro druckt eine Datei mit PROC print);
    %PUT %NRSTR(Aufruf %print%( data   * Dateiname);
    %PUT %NRSTR( optional:);
    %PUT %NRSTR(               ,var=   * Variablen);
    %PUT %NRSTR(             %););
    %RETURN;
%END;

* Prüfen der Parameter;

%IF %QUOTE(&data) EQ %THEN %DO;
    %PUT Fehler: Angabe des Dateinamens fehlt;
    %PUT Hilfe mit info=Y;
    %RETURN;
%END;

%IF NOT %SYSFUNC(EXIST(&data)) %THEN %DO;
    %PUT Fehler: Datei &data nicht gefunden;
    %PUT Hilfe mit info=Y;
    %RETURN;
%END;

* Ausgabe der Datei &data;

 TITLE "Datei &data";
 PROC PRINT DATA=&data LABEL;
%IF %QUOTE(&var) GT %THEN %DO;
    VAR &var;
%END;
 RUN;
%* Löschen der Überschrift;
 TITLE;

%* Sprungmarke für Hilfe und Fehlerbehandlung vor Version 9;
%ende:

%MEND;

%print;

Fehler: Angabe des Dateinamens fehlt
Hilfe mit info=Y

%print ( info=Y );

Dieses Macro druckt eine Datei mit PROC print
Aufruf %print( data   * Dateiname
 optional:
               ,var=   * Variablen
             );

OPTIONS MPRINT;

%print ( data=sasuser.class );

OPTIONS NOMPRINT;

131  OPTIONS MPRINT;
132
133  %print ( data=sasuser.class );
MPRINT(PRINT):   * PRüFEN DER PARAMETER;
MPRINT(PRINT):   * AUSGABE DER DATEI &DATA;
MPRINT(PRINT):   TITLE "Datei sasuser.class";
MPRINT(PRINT):   PROC PRINT DATA=SASUSER.CLASS LABEL;
MPRINT(PRINT):   RUN;

NOTE: The PROCEDURE PRINT used 0.33 seconds.


MPRINT(PRINT):   TITLE;
134
135  OPTIONS NOMPRINT;

 
Zurück zum SAS-Anwenderhandbuch